CMakeLists.txt 13 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372
  1. cmake_minimum_required(VERSION 3.12)
  2. # This can be read from ${PROJECT_NAME} after project() is called
  3. project(minetest)
  4. set(PROJECT_NAME_CAPITALIZED "Minetest")
  5. set(CMAKE_CXX_STANDARD 17)
  6. set(CMAKE_CXX_STANDARD_REQUIRED TRUE)
  7. set(GCC_MINIMUM_VERSION "7.5")
  8. set(CLANG_MINIMUM_VERSION "7.0.1")
  9. # You should not need to edit these manually, use util/bump_version.sh
  10. set(VERSION_MAJOR 5)
  11. set(VERSION_MINOR 9)
  12. set(VERSION_PATCH 0)
  13. set(VERSION_EXTRA "" CACHE STRING "Stuff to append to version string")
  14. # Change to false for releases
  15. set(DEVELOPMENT_BUILD TRUE)
  16. set(VERSION_STRING "${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH}")
  17. if(VERSION_EXTRA)
  18. set(VERSION_STRING "${VERSION_STRING}-${VERSION_EXTRA}")
  19. elseif(DEVELOPMENT_BUILD)
  20. set(VERSION_STRING "${VERSION_STRING}-dev")
  21. endif()
  22. if (CMAKE_BUILD_TYPE STREQUAL Debug)
  23. # Append "-debug" to version string
  24. set(VERSION_STRING "${VERSION_STRING}-debug")
  25. endif()
  26. # Configuration options
  27. set(BUILD_CLIENT TRUE CACHE BOOL "Build client")
  28. set(BUILD_SERVER FALSE CACHE BOOL "Build server")
  29. set(BUILD_UNITTESTS TRUE CACHE BOOL "Build unittests")
  30. set(BUILD_BENCHMARKS FALSE CACHE BOOL "Build benchmarks")
  31. set(BUILD_DOCUMENTATION TRUE CACHE BOOL "Build documentation")
  32. set(DEFAULT_ENABLE_LTO TRUE)
  33. # by default don't enable on Debug builds to get faster builds
  34. if(CMAKE_BUILD_TYPE STREQUAL "Debug")
  35. set(DEFAULT_ENABLE_LTO FALSE)
  36. endif()
  37. #### LTO testing list ####
  38. # - Linux: seems to work always
  39. # - win32/msvc: works
  40. # - win32/gcc: fails to link
  41. # - win32/clang: works
  42. # - macOS on x86: seems to be fine
  43. # - macOS on ARM: crashes, see <https://github.com/minetest/minetest/issues/14397>
  44. # Note: since CMake has no easy architecture detection disabling for Mac entirely
  45. #### ####
  46. if((WIN32 AND CMAKE_CXX_COMPILER_ID STREQUAL "GNU") OR APPLE)
  47. set(DEFAULT_ENABLE_LTO FALSE)
  48. endif()
  49. set(ENABLE_LTO ${DEFAULT_ENABLE_LTO} CACHE BOOL "Use Link Time Optimization")
  50. set(DEFAULT_RUN_IN_PLACE FALSE)
  51. if(WIN32)
  52. set(DEFAULT_RUN_IN_PLACE TRUE)
  53. endif()
  54. set(RUN_IN_PLACE ${DEFAULT_RUN_IN_PLACE} CACHE BOOL
  55. "Run directly in source directory structure")
  56. message(STATUS "*** Will build version ${VERSION_STRING} ***")
  57. message(STATUS "BUILD_CLIENT: " ${BUILD_CLIENT})
  58. message(STATUS "BUILD_SERVER: " ${BUILD_SERVER})
  59. message(STATUS "BUILD_UNITTESTS: " ${BUILD_UNITTESTS})
  60. message(STATUS "BUILD_BENCHMARKS: " ${BUILD_BENCHMARKS})
  61. message(STATUS "BUILD_DOCUMENTATION: " ${BUILD_DOCUMENTATION})
  62. message(STATUS "RUN_IN_PLACE: " ${RUN_IN_PLACE})
  63. set(WARN_ALL TRUE CACHE BOOL "Enable -Wall for Release build")
  64. if(NOT CMAKE_BUILD_TYPE)
  65. # Default to release
  66. set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type: Debug or Release" FORCE)
  67. endif()
  68. set(ENABLE_UPDATE_CHECKER (NOT ${DEVELOPMENT_BUILD}) CACHE BOOL
  69. "Whether to enable update checks by default")
  70. # Included stuff
  71. set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_SOURCE_DIR}/cmake/Modules/")
  72. # Load default options for Android
  73. if(ANDROID)
  74. cmake_minimum_required(VERSION 3.20)
  75. include(MinetestAndroidLibs)
  76. endif()
  77. if(TRUE)
  78. message(STATUS "Using imported IrrlichtMt at subdirectory 'irr'")
  79. if(BUILD_CLIENT)
  80. # tell IrrlichtMt to create a static library
  81. set(BUILD_SHARED_LIBS OFF CACHE BOOL "Build shared library" FORCE)
  82. add_subdirectory(irr EXCLUDE_FROM_ALL)
  83. unset(BUILD_SHARED_LIBS CACHE)
  84. if(NOT TARGET IrrlichtMt)
  85. message(FATAL_ERROR "IrrlichtMt project is missing a CMake target?!")
  86. endif()
  87. else()
  88. add_library(IrrlichtMt::IrrlichtMt INTERFACE IMPORTED)
  89. set_target_properties(IrrlichtMt::IrrlichtMt PROPERTIES
  90. INTERFACE_INCLUDE_DIRECTORIES "${CMAKE_CURRENT_SOURCE_DIR}/irr/include")
  91. endif()
  92. endif()
  93. if (ENABLE_LTO OR CMAKE_INTERPROCEDURAL_OPTIMIZATION)
  94. include(CheckIPOSupported)
  95. check_ipo_supported(RESULT lto_supported OUTPUT lto_output)
  96. if(lto_supported)
  97. set(CMAKE_INTERPROCEDURAL_OPTIMIZATION TRUE)
  98. message(STATUS "LTO/IPO is enabled")
  99. else()
  100. set(CMAKE_INTERPROCEDURAL_OPTIMIZATION FALSE)
  101. message(STATUS "LTO/IPO was requested but is not supported by the compiler: ${lto_output}")
  102. endif()
  103. else()
  104. message(STATUS "LTO/IPO is not enabled")
  105. endif()
  106. if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  107. if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS "${GCC_MINIMUM_VERSION}")
  108. message(FATAL_ERROR "Insufficient gcc version, found ${CMAKE_CXX_COMPILER_VERSION}. "
  109. "Version ${GCC_MINIMUM_VERSION} or higher is required.")
  110. endif()
  111. elseif(CMAKE_CXX_COMPILER_ID MATCHES "(Apple)?Clang")
  112. if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS "${CLANG_MINIMUM_VERSION}")
  113. message(FATAL_ERROR "Insufficient clang version, found ${CMAKE_CXX_COMPILER_VERSION}. "
  114. "Version ${CLANG_MINIMUM_VERSION} or higher is required.")
  115. endif()
  116. endif()
  117. # Installation
  118. if(WIN32)
  119. set(SHAREDIR ".")
  120. set(BINDIR "bin")
  121. set(DOCDIR "doc")
  122. set(EXAMPLE_CONF_DIR ".")
  123. set(LOCALEDIR "locale")
  124. elseif(APPLE)
  125. set(BUNDLE_NAME ${PROJECT_NAME}.app)
  126. set(BUNDLE_PATH "${BUNDLE_NAME}")
  127. set(BINDIR ${BUNDLE_NAME}/Contents/MacOS)
  128. set(SHAREDIR ${BUNDLE_NAME}/Contents/Resources)
  129. set(DOCDIR "${SHAREDIR}/${PROJECT_NAME}")
  130. set(EXAMPLE_CONF_DIR ${DOCDIR})
  131. set(LOCALEDIR "${SHAREDIR}/locale")
  132. elseif(UNIX) # Linux, BSD etc
  133. if(RUN_IN_PLACE)
  134. set(SHAREDIR ".")
  135. set(BINDIR "bin")
  136. set(DOCDIR "doc")
  137. set(EXAMPLE_CONF_DIR ".")
  138. set(MANDIR "unix/man")
  139. set(XDG_APPS_DIR "unix/applications")
  140. set(APPDATADIR "unix/metainfo")
  141. set(ICONDIR "unix/icons")
  142. set(LOCALEDIR "locale")
  143. else()
  144. include(GNUInstallDirs)
  145. set(SHAREDIR "${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME}")
  146. set(BINDIR "${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_BINDIR}")
  147. set(DOCDIR "${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_DOCDIR}")
  148. set(MANDIR "${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_MANDIR}")
  149. set(EXAMPLE_CONF_DIR ${DOCDIR})
  150. set(XDG_APPS_DIR "${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_DATADIR}/applications")
  151. set(APPDATADIR "${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_DATADIR}/metainfo")
  152. set(ICONDIR "${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_DATADIR}/icons")
  153. set(LOCALEDIR "${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_LOCALEDIR}")
  154. endif()
  155. endif()
  156. set(CUSTOM_SHAREDIR "" CACHE STRING "Directory to install data files into")
  157. if(NOT CUSTOM_SHAREDIR STREQUAL "")
  158. set(SHAREDIR "${CUSTOM_SHAREDIR}")
  159. message(STATUS "Using SHAREDIR=${SHAREDIR}")
  160. endif()
  161. set(CUSTOM_BINDIR "" CACHE STRING "Directory to install binaries into")
  162. if(NOT CUSTOM_BINDIR STREQUAL "")
  163. set(BINDIR "${CUSTOM_BINDIR}")
  164. message(STATUS "Using BINDIR=${BINDIR}")
  165. endif()
  166. set(CUSTOM_DOCDIR "" CACHE STRING "Directory to install documentation into")
  167. if(NOT CUSTOM_DOCDIR STREQUAL "")
  168. set(DOCDIR "${CUSTOM_DOCDIR}")
  169. if(NOT RUN_IN_PLACE)
  170. set(EXAMPLE_CONF_DIR ${DOCDIR})
  171. endif()
  172. message(STATUS "Using DOCDIR=${DOCDIR}")
  173. endif()
  174. set(CUSTOM_MANDIR "" CACHE STRING "Directory to install manpages into")
  175. if(NOT CUSTOM_MANDIR STREQUAL "")
  176. set(MANDIR "${CUSTOM_MANDIR}")
  177. message(STATUS "Using MANDIR=${MANDIR}")
  178. endif()
  179. set(CUSTOM_EXAMPLE_CONF_DIR "" CACHE STRING "Directory to install example config file into")
  180. if(NOT CUSTOM_EXAMPLE_CONF_DIR STREQUAL "")
  181. set(EXAMPLE_CONF_DIR "${CUSTOM_EXAMPLE_CONF_DIR}")
  182. message(STATUS "Using EXAMPLE_CONF_DIR=${EXAMPLE_CONF_DIR}")
  183. endif()
  184. set(CUSTOM_XDG_APPS_DIR "" CACHE STRING "Directory to install .desktop files into")
  185. if(NOT CUSTOM_XDG_APPS_DIR STREQUAL "")
  186. set(XDG_APPS_DIR "${CUSTOM_XDG_APPS_DIR}")
  187. message(STATUS "Using XDG_APPS_DIR=${XDG_APPS_DIR}")
  188. endif()
  189. set(CUSTOM_ICONDIR "" CACHE STRING "Directory to install icons into")
  190. if(NOT CUSTOM_ICONDIR STREQUAL "")
  191. set(ICONDIR "${CUSTOM_ICONDIR}")
  192. message(STATUS "Using ICONDIR=${ICONDIR}")
  193. endif()
  194. set(CUSTOM_LOCALEDIR "" CACHE STRING "Directory to install l10n files into")
  195. if(NOT CUSTOM_LOCALEDIR STREQUAL "")
  196. set(LOCALEDIR "${CUSTOM_LOCALEDIR}")
  197. message(STATUS "Using LOCALEDIR=${LOCALEDIR}")
  198. endif()
  199. install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/builtin" DESTINATION "${SHAREDIR}")
  200. if(RUN_IN_PLACE)
  201. install(FILES "${CMAKE_CURRENT_SOURCE_DIR}/mods/mods_here.txt" DESTINATION "${SHAREDIR}/mods")
  202. install(FILES "${CMAKE_CURRENT_SOURCE_DIR}/textures/texture_packs_here.txt" DESTINATION "${SHAREDIR}/textures")
  203. endif()
  204. set(INSTALL_DEVTEST FALSE CACHE BOOL "Install Development Test")
  205. if(INSTALL_DEVTEST)
  206. install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/games/devtest" DESTINATION "${SHAREDIR}/games/"
  207. PATTERN ".git*" EXCLUDE )
  208. endif()
  209. if(BUILD_CLIENT)
  210. install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/client/shaders" DESTINATION "${SHAREDIR}/client")
  211. install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/textures/base/pack" DESTINATION "${SHAREDIR}/textures/base")
  212. if(RUN_IN_PLACE)
  213. install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/clientmods" DESTINATION "${SHAREDIR}")
  214. install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/client/serverlist" DESTINATION "${SHAREDIR}/client")
  215. endif()
  216. endif()
  217. install(FILES "README.md" DESTINATION "${DOCDIR}" COMPONENT "Docs")
  218. install(FILES "doc/lua_api.md" DESTINATION "${DOCDIR}" COMPONENT "Docs")
  219. install(FILES "doc/client_lua_api.md" DESTINATION "${DOCDIR}" COMPONENT "Docs")
  220. install(FILES "doc/menu_lua_api.md" DESTINATION "${DOCDIR}" COMPONENT "Docs")
  221. install(FILES "doc/texture_packs.md" DESTINATION "${DOCDIR}" COMPONENT "Docs")
  222. install(FILES "doc/world_format.md" DESTINATION "${DOCDIR}" COMPONENT "Docs")
  223. install(FILES "minetest.conf.example" DESTINATION "${EXAMPLE_CONF_DIR}")
  224. if(UNIX AND NOT APPLE)
  225. install(FILES "doc/minetest.6" "doc/minetestserver.6" DESTINATION "${MANDIR}/man6")
  226. install(FILES "misc/net.minetest.minetest.desktop" DESTINATION "${XDG_APPS_DIR}")
  227. install(FILES "misc/net.minetest.minetest.appdata.xml" DESTINATION "${APPDATADIR}")
  228. install(FILES "misc/minetest.svg" DESTINATION "${ICONDIR}/hicolor/scalable/apps")
  229. install(FILES "misc/minetest-xorg-icon-128.png"
  230. DESTINATION "${ICONDIR}/hicolor/128x128/apps"
  231. RENAME "minetest.png")
  232. endif()
  233. if(APPLE)
  234. install(FILES "misc/minetest-icon.icns" DESTINATION "${SHAREDIR}")
  235. install(FILES "misc/Info.plist" DESTINATION "${BUNDLE_PATH}/Contents")
  236. endif()
  237. # Library pack
  238. find_package(GMP REQUIRED)
  239. find_package(Json REQUIRED)
  240. find_package(Lua REQUIRED)
  241. if(NOT USE_LUAJIT)
  242. add_subdirectory(lib/bitop)
  243. endif()
  244. if(BUILD_BENCHMARKS)
  245. add_subdirectory(lib/catch2)
  246. endif()
  247. # Subdirectories
  248. # Be sure to add all relevant definitions above this
  249. add_subdirectory(src)
  250. # CPack
  251. set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "A free open-source voxel game engine with easy modding and game creation.")
  252. set(CPACK_PACKAGE_VERSION_MAJOR ${VERSION_MAJOR})
  253. set(CPACK_PACKAGE_VERSION_MINOR ${VERSION_MINOR})
  254. set(CPACK_PACKAGE_VERSION_PATCH ${VERSION_PATCH})
  255. set(CPACK_PACKAGE_VENDOR "celeron55")
  256. set(CPACK_PACKAGE_CONTACT "Perttu Ahola <celeron55@gmail.com>")
  257. include(CPackComponent)
  258. cpack_add_component(Docs
  259. DISPLAY_NAME "Documentation"
  260. DESCRIPTION "Documentation about Minetest and Minetest modding"
  261. )
  262. if(WIN32)
  263. # Include all dynamically linked runtime libraries such as MSVCRxxx.dll
  264. include(InstallRequiredSystemLibraries)
  265. if(RUN_IN_PLACE)
  266. if(CMAKE_SIZEOF_VOID_P EQUAL 8)
  267. set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-win64")
  268. else()
  269. set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-win32")
  270. endif()
  271. set(CPACK_GENERATOR ZIP)
  272. else()
  273. set(CPACK_GENERATOR WIX)
  274. set(CPACK_PACKAGE_NAME "${PROJECT_NAME_CAPITALIZED}")
  275. set(CPACK_PACKAGE_INSTALL_DIRECTORY ".")
  276. set(CPACK_PACKAGE_EXECUTABLES ${PROJECT_NAME} "${PROJECT_NAME_CAPITALIZED}")
  277. set(CPACK_CREATE_DESKTOP_LINKS ${PROJECT_NAME})
  278. set(CPACK_PACKAGING_INSTALL_PREFIX "/${PROJECT_NAME_CAPITALIZED}")
  279. set(CPACK_WIX_PRODUCT_ICON "${CMAKE_CURRENT_SOURCE_DIR}/misc/minetest-icon.ico")
  280. # Supported languages can be found at
  281. # http://wixtoolset.org/documentation/manual/v3/wixui/wixui_localization.html
  282. #set(CPACK_WIX_CULTURES "ar-SA,bg-BG,ca-ES,hr-HR,cs-CZ,da-DK,nl-NL,en-US,et-EE,fi-FI,fr-FR,de-DE")
  283. set(CPACK_WIX_UI_BANNER "${CMAKE_CURRENT_SOURCE_DIR}/misc/CPACK_WIX_UI_BANNER.BMP")
  284. set(CPACK_WIX_UI_DIALOG "${CMAKE_CURRENT_SOURCE_DIR}/misc/CPACK_WIX_UI_DIALOG.BMP")
  285. set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/doc/lgpl-2.1.txt")
  286. # The correct way would be to include both x32 and x64 into one installer
  287. # and install the appropriate one.
  288. # CMake does not support that, so there are two separate GUID's
  289. if(CMAKE_SIZEOF_VOID_P EQUAL 8)
  290. set(CPACK_WIX_UPGRADE_GUID "745A0FB3-5552-44CA-A587-A91C397CCC56")
  291. else()
  292. set(CPACK_WIX_UPGRADE_GUID "814A2E2D-2779-4BBD-9ACD-FC3BD51FBBA2")
  293. endif()
  294. endif()
  295. elseif(APPLE)
  296. set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  297. set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-osx")
  298. set(CPACK_GENERATOR ZIP)
  299. else()
  300. set(CPACK_PACKAGE_FILE_NAME "${PROJECT_NAME}-${VERSION_STRING}-linux")
  301. set(CPACK_GENERATOR TGZ)
  302. set(CPACK_SOURCE_GENERATOR TGZ)
  303. endif()
  304. include(CPack)
  305. # Add a target to generate API documentation with Doxygen
  306. if(BUILD_DOCUMENTATION)
  307. find_package(Doxygen)
  308. if(DOXYGEN_FOUND)
  309. configure_file(${CMAKE_CURRENT_SOURCE_DIR}/doc/Doxyfile.in
  310. ${CMAKE_CURRENT_BINARY_DIR}/doc/Doxyfile @ONLY)
  311. add_custom_target(doc
  312. ${DOXYGEN_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/doc/Doxyfile
  313. WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/doc
  314. COMMENT "Generating API documentation with Doxygen" VERBATIM
  315. )
  316. endif()
  317. endif()