Browse Source

build: remove automake/autoconf build system

Signed-off-by: Jo-Philipp Wich <jo@mein.io>
Jo-Philipp Wich 7 years ago
parent
commit
6215c27b1d
11 changed files with 0 additions and 627 deletions
  1. 0 37
      Makefile.am
  2. 0 5
      autogen.sh
  3. 0 309
      configure.ac
  4. 0 26
      libbb/Makefile.am
  5. 0 11
      libopkg.pc.in
  6. 0 48
      libopkg/Makefile.am
  7. 0 157
      m4/pkg.m4
  8. 0 2
      man/Makefile.am
  9. 0 6
      src/Makefile.am
  10. 0 23
      tests/Makefile.am
  11. 0 3
      utils/Makefile.am

+ 0 - 37
Makefile.am

@@ -1,37 +0,0 @@
-ACLOCAL_AMFLAGS = -I m4
-
-SUBDIRS = libbb libopkg src tests utils man
-
-
-HOST_CPU=@host_cpu@
-BUILD_CPU=@build_cpu@
-OPKGLIBDIR=@opkglibdir@ 
-ALL_CFLAGS=-g -O -Wall -DHOST_CPU_STR=\"@host_cpu@\" -DBUILD_CPU=@build_cpu@ -DLIBDIR=\"@libdir@\" -DOPKGLIBDIR=\"@opkglibdir@\" -DDATADIR=\"@datadir@\"
-
-PATHFINDER_CFLAGS = @PATHFINDER_CFLAGS@
-PATHFINDER_LIBS   = @PATHFINDER_LIBS@
-
-pkgconfigdir = $(libdir)/pkgconfig
-pkgconfig_DATA = libopkg.pc
-
-
-
-interceptdir = $(datadir)/opkg/intercept
-intercept_DATA = intercept/ldconfig intercept/depmod intercept/update-modules
-
-install-data-hook:
-	chmod +x $(DESTDIR)$(datadir)/opkg/intercept/*
-
-EXTRA_DIST = $(intercept_DATA)
-
-MAINTAINERCLEANFILES= \
-	configure \
-	Makefile.in \
-	config.guess \
-	config.sub \
-	ltmain.sh \
-	.Makefile.am.swp \
-	aclocal.m4
-
-package: all-recursive
-	STRIPPROG=$(STRIP) INSTALL=$$PWD/install-sh  binary-arch

+ 0 - 5
autogen.sh

@@ -1,5 +0,0 @@
-#! /bin/sh
-autoreconf -v --install || exit 1
-glib-gettextize --force --copy || exit 1
-./configure "$@"
-

+ 0 - 309
configure.ac

@@ -1,309 +0,0 @@
-# Process this file with autoconf to produce a configure script
-AC_INIT([opkg], [0.1.8])
-AC_CONFIG_SRCDIR([libopkg/pkg.c])
-
-AC_CONFIG_AUX_DIR([conf])
-AC_CONFIG_MACRO_DIR([m4])
-
-AM_INIT_AUTOMAKE
-AM_CONFIG_HEADER(libopkg/config.h)
-
-AC_CANONICAL_HOST
-AC_GNU_SOURCE 
-
-# Disable C++/Fortran checks
-define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])
-define([AC_LIBTOOL_LANG_F77_CONFIG], [:])
-
-
-for top_builddir in . .. ../.. $ac_auxdir $ac_auxdir/..; do
-  test -f $top_builddir/configure && break
-done
-
-# large file support can be useful for gpgme
-AC_SYS_LARGEFILE
-
-
-# Checks for programs
-AC_PROG_AWK
-AC_PROG_CC
-AC_PROG_INSTALL
-AC_PROG_LN_S
-AM_PROG_INSTALL_STRIP
-AC_PROG_LIBTOOL
-PKG_PROG_PKG_CONFIG([0.20])
-
-# Checks for libraries
-
-dnl extra argument: --enable-pathfinder
-AC_ARG_ENABLE(pathfinder,
-              AC_HELP_STRING([--enable-pathfinder], [Enable libpathfinder support.
-      [[default=no]] ]),
-    [want_pathfinder="$enableval"], [want_pathfinder="no"])
-dnl Check for libpathfinder
-if test "x$want_pathfinder" = "xyes"; then
-  PKG_CHECK_MODULES([PATHFINDER], [pathfinder-openssl dbus-1 openssl])
-  if test -n "$PATHFINDER_CFLAGS$PATHFINDER_LIBS"; then
-    AC_DEFINE(HAVE_PATHFINDER, 1, [we have pathfinder])
-  fi
-  AC_SUBST(PATHFINDER_CFLAGS)
-  AC_SUBST(PATHFINDER_LIBS)
-fi
-AM_CONDITIONAL(HAVE_PATHFINDER, test "x$want_pathfinder" = "xyes")
-
-# check for libcurl
-AC_ARG_ENABLE(curl,
-              AC_HELP_STRING([--enable-curl], [Enable downloading with curl
-      [[default=yes]] ]),
-    [want_curl="$enableval"], [want_curl="yes"])
-
-if test "x$want_curl" = "xyes"; then
-  PKG_CHECK_MODULES(CURL, [libcurl])
-  AC_DEFINE(HAVE_CURL, 1, [Define if you want CURL support])
-fi
-
-# check for sha256
-AC_ARG_ENABLE(sha256,
-              AC_HELP_STRING([--enable-sha256], [Enable sha256sum check
-      (sha256.{c,h} are GPLv3 licensed) [[default=no]] ]),
-    [want_sha256="$enableval"], [want_sha256="no"])
-
-AC_ARG_ENABLE(md5,
-              AC_HELP_STRING([--enable-md5], [Enable md5sum check
-      (md5.{c,h} are GPLv3 licensed) [[default=no]] ]),
-    [want_md5="$enableval"], [want_md5="yes"])
-
-if test "x$want_sha256" = "xyes"; then
-  AC_DEFINE(HAVE_SHA256, 1, [Define if you want sha256 support])
-fi
-if test "x$want_md5" = "xyes"; then
-  AC_DEFINE(HAVE_MD5, 1, [Define if you want md5 support])
-fi
-AM_CONDITIONAL(HAVE_SHA256, test "x$want_sha256" = "xyes")
-AM_CONDITIONAL(HAVE_MD5, test "x$want_md5" = "xyes")
-
-# check for openssl
-AC_ARG_ENABLE(openssl,
-              AC_HELP_STRING([--enable-openssl], [Enable signature checking with OpenSSL
-      [[default=no]] ]),
-    [want_openssl="$enableval"], [want_openssl="no"])
-
-if test "x$want_openssl" = "xyes"; then
-  AC_DEFINE(HAVE_OPENSSL, 1, [Define if you want OpenSSL support])
-  NEED_SSL_LIBS="yes"
-fi
-
-# check for libssl-curl
-AC_ARG_ENABLE(ssl-curl,
-              AC_HELP_STRING([--enable-ssl-curl], [Enable certificate authentication with curl
-                              [[default="yes"]] ]),
-                              [want_sslcurl="$enableval"], [want_sslcurl="yes"])
-
-if test "x$want_curl" = "xyes" -a "x$want_sslcurl" = "xyes"; then
-  AC_DEFINE(HAVE_CURL, 1, [Define if you want CURL support])
-  AC_DEFINE(HAVE_SSLCURL, 1, [Define if you want certificate authentication with curl])
-  NEED_SSL_LIBS="yes"
-fi
-
-if test "x$NEED_SSL_LIBS" = "xyes"; then
-  AC_MSG_CHECKING([if openssl is available])
-
-  PKG_CHECK_MODULES(OPENSSL, openssl, [:], [:])
-  if test "x$OPENSSL_LIBS" != "x"; then
-          AC_MSG_RESULT(yes)
-  else
-          OPENSSL_LIBS="-lcrypto -lssl"
-          dnl If pkg-config fails, run compile/link test.
-          AC_TRY_LINK([
-#include <openssl/opensslv.h>
-], [
-return OPENSSL_VERSION_NUMBER; ],
-          [
-            AC_MSG_RESULT(yes)
-
-          ], [
-            AC_MSG_RESULT(no)
-            AC_MSG_ERROR(OpenSSL not found)
-          ])
-  fi
-  AC_SUBST(OPENSSL_LIBS)
-fi
-
-
-dnl **********
-dnl GPGME
-dnl **********
-
-AC_ARG_ENABLE(gpg,
-    AC_HELP_STRING([--enable-gpg], [Enable signature checking with gpgme
-      [[default=yes]] ]),
-    [want_gpgme="$enableval"], [want_gpgme="yes"])
-
-if test "x$want_gpgme" = "xyes"; then
-  ok="no"
-  min_gpgme_version=1.0.0
-  AC_PATH_PROG(GPGME_CONFIG, gpgme-config, "failed")
-  if test $GPGME_CONFIG != "failed" ; then
-	AC_MSG_CHECKING(for GPGME - version >= $min_gpgme_version)
-	req_major=`echo $min_gpgme_version | \
-		   sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
-	req_minor=`echo $min_gpgme_version | \
-		   sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
-	req_micro=`echo $min_gpgme_version | \
-		   sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\3/'`
-	gpgme_config_version=`$GPGME_CONFIG --version`
-	major=`echo $gpgme_config_version | \
-		   sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
-	minor=`echo $gpgme_config_version | \
-		   sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
-	micro=`echo $gpgme_config_version | \
-		   sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`
-
-	  if test "$major" -eq "$req_major"; then
-	     if test "$minor" -ge "$req_minor"; then
-	       if test "$micro" -ge "$req_micro"; then
-		 ok="yes"
-	       fi
-	     fi
-	  fi
-  fi
-
-  if test $ok = "yes"; then
-    GPGME_CFLAGS=`$GPGME_CONFIG --cflags`
-    GPGME_LIBS=`$GPGME_CONFIG --libs`
-    AC_MSG_RESULT(yes)
-    AC_DEFINE(HAVE_GPGME, 1, [Define if you want GPG support])
-  else
-    AC_MSG_ERROR(GPGME $min_gpgme_version or later needed)
-  fi
-fi
-
-AC_ARG_ENABLE(usign,
-    AC_HELP_STRING([--enable-usign], [Enable signature checking with usign
-      [[default=yes]] ]),
-    [want_usign="$enableval"], [want_usign="yes"])
-
-if test "x$want_usign" = "xyes"; then
-  AC_DEFINE(HAVE_USIGN, 1, [Define if you want usign support])
-fi
-
-AC_SUBST(GPGME_CFLAGS)
-AC_SUBST(GPGME_LIBS)
-
-
-# Checks for header files
-AC_HEADER_DIRENT
-AC_HEADER_STDC
-AC_HEADER_SYS_WAIT
-AC_CHECK_HEADERS([errno.h fcntl.h memory.h regex.h stddef.h stdlib.h string.h strings.h unistd.h utime.h])
-
-# Checks for typedefs, structures, and compiler characteristics.
-AC_C_CONST
-AC_TYPE_UID_T
-AC_TYPE_MODE_T
-AC_TYPE_OFF_T
-AC_TYPE_PID_T
-AC_TYPE_SIZE_T
-AC_CHECK_MEMBERS([struct stat.st_rdev])
-
-# Checks endianness
-AC_C_BIGENDIAN(BIGENDIAN_CFLAGS="-DWORDS_BIGENDIAN=1",)
-AC_SUBST(BIGENDIAN_CFLAGS)
-
-# Don't do annoying tests that don't work when cross-compiling, just trust them.
-# The AC_FUNC_MEMCMP test doesn't work during a cross-compile, disable.
-# AC_FUNC_MEMCMP
-# The AC_FUNC_STAT test doesn't work during a cross-compile, disable.
-# AC_FUNC_STAT
-
-# Checks for library functions
-AC_FUNC_CHOWN
-AC_FUNC_FORK
-AC_TYPE_SIGNAL
-AC_FUNC_UTIME_NULL
-AC_FUNC_VPRINTF
-AC_CHECK_FUNCS([memmove memset mkdir regcomp strchr strcspn strdup strerror strndup strrchr strstr strtol strtoul sysinfo utime])
-
-opkglibdir=
-AC_ARG_WITH(opkglibdir,
-[  --with-opkglibdir=DIR   specifies directory to put status and info files.
-                          "/opkg" is always added so if you want your files 
-                          to be in /var/lib/opkg instead of /usr/lib/opkg
-                          you should indicate 
-                          --with-opkglibdir=/var/lib ],
-[case "${withval}" in
-yes)    AC_MSG_ERROR(bad value ${withval} given for opkg libs directories ) ;;
-no)     ;;
-*)      opkglibdir=$with_opkglibdir ;;
-esac])
-
-# Default local prefix if it is empty
-if test x$opkglibdir = x; then
-        opkglibdir=/usr/lib
-fi
-
-opkgetcdir=
-AC_ARG_WITH(opkgetcdir,
-[  --with-opkgetcdir=DIR   specifies directory for opkg.conf file,
-                           "/opkg" is always added so if you want your files
-                           to be in /usr/etc/opkg instead of /etc/opkg
-                           you should indicate
-                           --with-opkgetcdir=/usr/etc ],
-[case "${withval}" in
-yes)    AC_MSG_ERROR(bad value ${withval} given for opkg.conf directory ) ;;
-no)     ;;
-*)      opkgetcdir=$with_opkgetcdir ;;
-esac])
-
-# Default local prefix if it is empty
-if test x$opkgetcdir = x; then
-        opkgetcdir=/etc
-fi
-
-opkglockfile=
-AC_ARG_WITH(opkglockfile,
-[  --with-opkglockfile=FILE specifies the file used to make sure there is only
-                           one instance of opkg runnning.
-                           Defaults to ${opkglibdir}/opkg/lock, i.e.
-                           /usr/lib/opkg/lock ],
-[case "${withval}" in
-yes)    AC_MSG_ERROR(bad value ${withval} given for opkg lock file ) ;;
-no)     ;;
-*)      opkglockfile=$with_opkglockfile ;;
-esac])
-
-# Default if empty
-if test x$opkglockfile = x; then
-        opkglockfile=${opkglibdir}/opkg/lock
-fi
-
-dnl Some special cases for the wow64 build
-if test "x$want_gpgme" = "xyes"
-then
-	if test "x$want_openssl" = "xyes"
-	then
-	AC_MSG_ERROR([--enable-gpg and --enable-openssl are mutually exclusive.
-Use --disable-gpg if you want OpenSSL smime signatures])
-	fi
-fi
-
-CLEAN_DATE=`date +"%B %Y" | tr -d '\n'`
-
-AC_SUBST(opkglibdir)
-AC_SUBST(opkgetcdir)
-AC_SUBST(opkglockfile)
-AC_SUBST([CLEAN_DATE])
-
-AC_OUTPUT(
-    Makefile
-    libopkg/Makefile
-    tests/Makefile
-    src/Makefile
-    libbb/Makefile
-    utils/Makefile
-    utils/update-alternatives
-    libopkg.pc
-    man/Makefile
-    man/opkg-cl.1
-    man/opkg-key.1
-    )

+ 0 - 26
libbb/Makefile.am

@@ -1,26 +0,0 @@
-HOST_CPU=@host_cpu@
-BUILD_CPU=@build_cpu@
-ALL_CFLAGS=-g -O -Wall -DHOST_CPU_STR=\"$(HOST_CPU)\" -DBUILD_CPU=@build_cpu@
-
-noinst_LIBRARIES = libbb.a
-
-libbb_a_SOURCES = \
-	libbb.h \
-	wfopen.c \
-	unarchive.c \
-	copy_file.c \
-	copy_file_chunk.c \
-	xreadlink.c \
-	concat_path_file.c \
-	xfuncs.c \
-	last_char_is.c \
-	make_directory.c \
-	safe_strncpy.c \
-	parse_mode.c \
-	time_string.c \
-	all_read.c \
-	mode_string.c \
-	gzip.c
-
-libbb_la_CFLAGS = $(ALL_CFLAGS)
-#libbb_la_LDFLAGS = -static

+ 0 - 11
libopkg.pc.in

@@ -1,11 +0,0 @@
-prefix=@prefix@
-exec_prefix=${prefix}
-libdir=${exec_prefix}/lib
-includedir=${prefix}/include
-
-Name: libopkg
-Description: opkg package manager library
-Version: @VERSION@
-Libs: -L${libdir} -lopkg
-Cflags: -I${includedir}/libopkg
-

+ 0 - 48
libopkg/Makefile.am

@@ -1,48 +0,0 @@
-HOST_CPU=@host_cpu@
-AM_CFLAGS=-Wall -DHOST_CPU_STR=\"$(HOST_CPU)\" -DBUILD_CPU=@build_cpu@ -DLIBDIR=\"@libdir@\" -DOPKGLIBDIR=\"@opkglibdir@\" -DOPKGETCDIR=\"@opkgetcdir@\" -DOPKGLOCKFILE=\"@opkglockfile@\" -DDATADIR=\"@datadir@\" -I$(top_srcdir) $(BIGENDIAN_CFLAGS) $(CURL_CFLAGS) $(GPGME_CFLAGS) $(PATHFINDER_CFLAGS)
-
-libopkg_includedir=$(includedir)/libopkg
-libopkg_include_HEADERS= *.h
-
-
-opkg_libcore_sources = \
-		    opkg.c opkg.h \
-		    opkg_defines.h
-opkg_cmd_sources = opkg_cmd.c opkg_cmd.h \
-		   opkg_configure.c opkg_configure.h \
-		   opkg_download.c opkg_download.h \
-		   opkg_install.c opkg_install.h \
-		   opkg_upgrade.c opkg_upgrade.h \
-		   opkg_remove.c opkg_remove.h
-opkg_db_sources = opkg_conf.c opkg_conf.h \
-		  opkg_utils.c opkg_utils.h pkg.c pkg.h hash_table.h \
-		  pkg_depends.c pkg_depends.h pkg_extract.c pkg_extract.h \
-		  hash_table.c pkg_hash.c pkg_hash.h pkg_parse.c pkg_parse.h \
-		  pkg_vec.c pkg_vec.h
-opkg_list_sources = conffile.c conffile.h conffile_list.c conffile_list.h \
-		    nv_pair.c nv_pair.h nv_pair_list.c nv_pair_list.h \
-		    pkg_dest.c pkg_dest.h pkg_dest_list.c pkg_dest_list.h \
-		    pkg_src.c pkg_src.h pkg_src_list.c pkg_src_list.h \
-		    str_list.c str_list.h void_list.c void_list.h \
-		    active_list.c active_list.h list.h 
-opkg_util_sources = file_util.c file_util.h opkg_message.h opkg_message.c \
-		    parse_util.c parse_util.h \
-		    sprintf_alloc.c sprintf_alloc.h \
-		    xregex.c xregex.h xsystem.c xsystem.h
-if HAVE_PATHFINDER
-opkg_util_sources += opkg_pathfinder.c opkg_pathfinder.h
-endif
-if HAVE_MD5
-opkg_util_sources += md5.c md5.h
-endif
-if HAVE_SHA256
-opkg_util_sources += sha256.c sha256.h
-endif
-
-noinst_LIBRARIES = libopkg.a
-libopkg_a_SOURCES = \
-	$(opkg_libcore_sources) \
-	$(opkg_cmd_sources) $(opkg_db_sources) \
-	$(opkg_util_sources) $(opkg_list_sources)
-
-libopkg_a_LIBADD = $(top_builddir)/libbb/libbb.a

+ 0 - 157
m4/pkg.m4

@@ -1,157 +0,0 @@
-# pkg.m4 - Macros to locate and utilise pkg-config.            -*- Autoconf -*-
-# 
-# Copyright © 2004 Scott James Remnant <scott@netsplit.com>.
-#
-# This program is free software; you can redistribute it and/or modify
-# it under the terms of the GNU General Public License as published by
-# the Free Software Foundation; either version 2 of the License, or
-# (at your option) any later version.
-#
-# This program is distributed in the hope that it will be useful, but
-# WITHOUT ANY WARRANTY; without even the implied warranty of
-# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
-# General Public License for more details.
-#
-# You should have received a copy of the GNU General Public License
-# along with this program; if not, write to the Free Software
-# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
-#
-# As a special exception to the GNU General Public License, if you
-# distribute this file as part of a program that contains a
-# configuration script generated by Autoconf, you may include it under
-# the same distribution terms that you use for the rest of that program.
-
-# PKG_PROG_PKG_CONFIG([MIN-VERSION])
-# ----------------------------------
-AC_DEFUN([PKG_PROG_PKG_CONFIG],
-[m4_pattern_forbid([^_?PKG_[A-Z_]+$])
-m4_pattern_allow([^PKG_CONFIG(_PATH)?$])
-AC_ARG_VAR([PKG_CONFIG], [path to pkg-config utility])dnl
-if test "x$ac_cv_env_PKG_CONFIG_set" != "xset"; then
-	AC_PATH_TOOL([PKG_CONFIG], [pkg-config])
-fi
-if test -n "$PKG_CONFIG"; then
-	_pkg_min_version=m4_default([$1], [0.9.0])
-	AC_MSG_CHECKING([pkg-config is at least version $_pkg_min_version])
-	if $PKG_CONFIG --atleast-pkgconfig-version $_pkg_min_version; then
-		AC_MSG_RESULT([yes])
-	else
-		AC_MSG_RESULT([no])
-		PKG_CONFIG=""
-	fi
-		
-fi[]dnl
-])# PKG_PROG_PKG_CONFIG
-
-# PKG_CHECK_EXISTS(MODULES, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
-#
-# Check to see whether a particular set of modules exists.  Similar
-# to PKG_CHECK_MODULES(), but does not set variables or print errors.
-#
-#
-# Similar to PKG_CHECK_MODULES, make sure that the first instance of
-# this or PKG_CHECK_MODULES is called, or make sure to call
-# PKG_CHECK_EXISTS manually
-# --------------------------------------------------------------
-AC_DEFUN([PKG_CHECK_EXISTS],
-[AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
-if test -n "$PKG_CONFIG" && \
-    AC_RUN_LOG([$PKG_CONFIG --exists --print-errors "$1"]); then
-  m4_ifval([$2], [$2], [:])
-m4_ifvaln([$3], [else
-  $3])dnl
-fi])
-
-
-# _PKG_CONFIG([VARIABLE], [COMMAND], [MODULES])
-# ---------------------------------------------
-m4_define([_PKG_CONFIG],
-[if test -n "$PKG_CONFIG"; then
-    if test -n "$$1"; then
-        pkg_cv_[]$1="$$1"
-    else
-        PKG_CHECK_EXISTS([$3],
-                         [pkg_cv_[]$1=`$PKG_CONFIG --[]$2 "$3" 2>/dev/null`],
-			 [pkg_failed=yes])
-    fi
-else
-	pkg_failed=untried
-fi[]dnl
-])# _PKG_CONFIG
-
-# _PKG_SHORT_ERRORS_SUPPORTED
-# -----------------------------
-AC_DEFUN([_PKG_SHORT_ERRORS_SUPPORTED],
-[AC_REQUIRE([PKG_PROG_PKG_CONFIG])
-if $PKG_CONFIG --atleast-pkgconfig-version 0.20; then
-        _pkg_short_errors_supported=yes
-else
-        _pkg_short_errors_supported=no
-fi[]dnl
-])# _PKG_SHORT_ERRORS_SUPPORTED
-
-
-# PKG_CHECK_MODULES(VARIABLE-PREFIX, MODULES, [ACTION-IF-FOUND],
-# [ACTION-IF-NOT-FOUND])
-#
-#
-# Note that if there is a possibility the first call to
-# PKG_CHECK_MODULES might not happen, you should be sure to include an
-# explicit call to PKG_PROG_PKG_CONFIG in your configure.ac
-#
-#
-# --------------------------------------------------------------
-AC_DEFUN([PKG_CHECK_MODULES],
-[AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
-AC_ARG_VAR([$1][_CFLAGS], [C compiler flags for $1, overriding pkg-config])dnl
-AC_ARG_VAR([$1][_LIBS], [linker flags for $1, overriding pkg-config])dnl
-
-pkg_failed=no
-AC_MSG_CHECKING([for $1])
-
-_PKG_CONFIG([$1][_CFLAGS], [cflags], [$2])
-_PKG_CONFIG([$1][_LIBS], [libs], [$2])
-
-m4_define([_PKG_TEXT], [Alternatively, you may set the environment variables $1[]_CFLAGS
-and $1[]_LIBS to avoid the need to call pkg-config.
-See the pkg-config man page for more details.])
-
-if test $pkg_failed = yes; then
-        _PKG_SHORT_ERRORS_SUPPORTED
-        if test $_pkg_short_errors_supported = yes; then
-	        $1[]_PKG_ERRORS=`$PKG_CONFIG --short-errors --errors-to-stdout --print-errors "$2"`
-        else 
-	        $1[]_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
-        fi
-	# Put the nasty error message in config.log where it belongs
-	echo "$$1[]_PKG_ERRORS" >&AS_MESSAGE_LOG_FD
-
-	ifelse([$4], , [AC_MSG_ERROR(dnl
-[Package requirements ($2) were not met:
-
-$$1_PKG_ERRORS
-
-Consider adjusting the PKG_CONFIG_PATH environment variable if you
-installed software in a non-standard prefix.
-
-_PKG_TEXT
-])],
-		[AC_MSG_RESULT([no])
-                $4])
-elif test $pkg_failed = untried; then
-	ifelse([$4], , [AC_MSG_FAILURE(dnl
-[The pkg-config script could not be found or is too old.  Make sure it
-is in your PATH or set the PKG_CONFIG environment variable to the full
-path to pkg-config.
-
-_PKG_TEXT
-
-To get pkg-config, see <http://pkg-config.freedesktop.org/>.])],
-		[$4])
-else
-	$1[]_CFLAGS=$pkg_cv_[]$1[]_CFLAGS
-	$1[]_LIBS=$pkg_cv_[]$1[]_LIBS
-        AC_MSG_RESULT([yes])
-	ifelse([$3], , :, [$3])
-fi[]dnl
-])# PKG_CHECK_MODULES

+ 0 - 2
man/Makefile.am

@@ -1,2 +0,0 @@
-man_MANS=opkg-cl.1 \
-  opkg-key.1

+ 0 - 6
src/Makefile.am

@@ -1,6 +0,0 @@
-AM_CFLAGS = -I${top_srcdir}/libopkg ${ALL_CFLAGS}
-bin_PROGRAMS = opkg-cl
-
-opkg_cl_SOURCES = opkg-cl.c
-opkg_cl_LDADD = $(top_builddir)/libopkg/libopkg.a \
-                $(top_builddir)/libbb/libbb.a $(CURL_LIBS) $(GPGME_LIBS) $(OPENSSL_LIBS) $(PATHFINDER_LIBS) -lpthread -lubox

+ 0 - 23
tests/Makefile.am

@@ -1,23 +0,0 @@
-AM_CFLAGS = $(ALL_CFLAGS) -Wall -g -O3 -I${top_srcdir}/libopkg
-
-#noinst_PROGRAMS = opkg_hash_test opkg_extract_test
-#noinst_PROGRAMS = libopkg_test opkg_active_list_test
-noinst_PROGRAMS = libopkg_test
-
-#opkg_hash_test_LDADD = $(top_builddir)/libbb/libbb.a $(top_builddir)/libopkg/libopkg.a
-#opkg_hash_test_SOURCES = opkg_hash_test.c
-#opkg_hash_test_CFLAGS = $(ALL_CFLAGS) -I$(top_srcdir)
-
-#opkg_extract_test_LDADD = $(top_builddir)/libbb/libbb.a $(top_builddir)/libopkg/libopkg.a
-#opkg_extract_test_SOURCES = opkg_extract_test.c
-#opkg_extract_test_CFLAGS = $(ALL_CFLAGS) -I$(top_srcdir)
-
-#opkg_active_list_test_LDADD = $(top_builddir)/libopkg/active_list.o
-#opkg_active_list_test_SOURCES = opkg_active_list_test.c
-#opkg_active_list_test_CFLAGS = $(ALL_CFLAGS) -I$(top_srcdir)
-
-libopkg_test_LDADD = $(top_builddir)/libopkg/libopkg.a $(top_builddir)/libbb/libbb.a $(CURL_LIBS) $(GPGME_LIBS) $(OPENSSL_LIBS) $(PATHFINDER_LIBS) -lpthread -lubox
-libopkg_test_SOURCE = libopkg_test.c
-libopkg_test_LDFLAGS = -static
-
-

+ 0 - 3
utils/Makefile.am

@@ -1,3 +0,0 @@
-bin_SCRIPTS = update-alternatives opkg-key
-
-EXTRA_DIST = $(bin_SCRIPTS)