memmove.s 4.3 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224
  1. TS = 0
  2. TE = 1
  3. FROM = 2
  4. N = 3
  5. TMP = 3 /* N and TMP don't overlap */
  6. TMP1 = 4
  7. TEXT memcpy(SB), $-4
  8. B _memmove
  9. TEXT memmove(SB), $-4
  10. _memmove:
  11. MOVW R(TS), to+0(FP) /* need to save for return value */
  12. MOVW from+4(FP), R(FROM)
  13. MOVW n+8(FP), R(N)
  14. ADD R(N), R(TS), R(TE) /* to end pointer */
  15. CMP R(FROM), R(TS)
  16. BLS _forward
  17. _back:
  18. ADD R(N), R(FROM) /* from end pointer */
  19. CMP $4, R(N) /* need at least 4 bytes to copy */
  20. BLT _b1tail
  21. _b4align: /* align destination on 4 */
  22. AND.S $3, R(TE), R(TMP)
  23. BEQ _b4aligned
  24. MOVBU.W -1(R(FROM)), R(TMP) /* pre-indexed */
  25. MOVBU.W R(TMP), -1(R(TE)) /* pre-indexed */
  26. B _b4align
  27. _b4aligned: /* is source now aligned? */
  28. AND.S $3, R(FROM), R(TMP)
  29. BNE _bunaligned
  30. ADD $31, R(TS), R(TMP) /* do 32-byte chunks if possible */
  31. _b32loop:
  32. CMP R(TMP), R(TE)
  33. BLS _b4tail
  34. MOVM.DB.W (R(FROM)), [R4-R11]
  35. MOVM.DB.W [R4-R11], (R(TE))
  36. B _b32loop
  37. _b4tail: /* do remaining words if possible */
  38. ADD $3, R(TS), R(TMP)
  39. _b4loop:
  40. CMP R(TMP), R(TE)
  41. BLS _b1tail
  42. MOVW.W -4(R(FROM)), R(TMP1) /* pre-indexed */
  43. MOVW.W R(TMP1), -4(R(TE)) /* pre-indexed */
  44. B _b4loop
  45. _b1tail: /* remaining bytes */
  46. CMP R(TE), R(TS)
  47. BEQ _return
  48. MOVBU.W -1(R(FROM)), R(TMP) /* pre-indexed */
  49. MOVBU.W R(TMP), -1(R(TE)) /* pre-indexed */
  50. B _b1tail
  51. _forward:
  52. CMP $4, R(N) /* need at least 4 bytes to copy */
  53. BLT _f1tail
  54. _f4align: /* align destination on 4 */
  55. AND.S $3, R(TS), R(TMP)
  56. BEQ _f4aligned
  57. MOVBU.P 1(R(FROM)), R(TMP) /* implicit write back */
  58. MOVBU.P R(TMP), 1(R(TS)) /* implicit write back */
  59. B _f4align
  60. _f4aligned: /* is source now aligned? */
  61. AND.S $3, R(FROM), R(TMP)
  62. BNE _funaligned
  63. SUB $31, R(TE), R(TMP) /* do 32-byte chunks if possible */
  64. _f32loop:
  65. CMP R(TMP), R(TS)
  66. BHS _f4tail
  67. MOVM.IA.W (R(FROM)), [R4-R11]
  68. MOVM.IA.W [R4-R11], (R(TS))
  69. B _f32loop
  70. _f4tail:
  71. SUB $3, R(TE), R(TMP) /* do remaining words if possible */
  72. _f4loop:
  73. CMP R(TMP), R(TS)
  74. BHS _f1tail
  75. MOVW.P 4(R(FROM)), R(TMP1) /* implicit write back */
  76. MOVW.P R4, 4(R(TS)) /* implicit write back */
  77. B _f4loop
  78. _f1tail:
  79. CMP R(TS), R(TE)
  80. BEQ _return
  81. MOVBU.P 1(R(FROM)), R(TMP) /* implicit write back */
  82. MOVBU.P R(TMP), 1(R(TS)) /* implicit write back */
  83. B _f1tail
  84. _return:
  85. MOVW to+0(FP), R0
  86. RET
  87. RSHIFT = 4
  88. LSHIFT = 5
  89. OFFSET = 6
  90. BR0 = 7
  91. BW0 = 8
  92. BR1 = 8
  93. BW1 = 9
  94. BR2 = 9
  95. BW2 = 10
  96. BR3 = 10
  97. BW3 = 11
  98. _bunaligned:
  99. CMP $2, R(TMP) /* is R(TMP) < 2 ? */
  100. MOVW.LT $8, R(RSHIFT) /* (R(n)<<24)|(R(n-1)>>8) */
  101. MOVW.LT $24, R(LSHIFT)
  102. MOVW.LT $1, R(OFFSET)
  103. MOVW.EQ $16, R(RSHIFT) /* (R(n)<<16)|(R(n-1)>>16) */
  104. MOVW.EQ $16, R(LSHIFT)
  105. MOVW.EQ $2, R(OFFSET)
  106. MOVW.GT $24, R(RSHIFT) /* (R(n)<<8)|(R(n-1)>>24) */
  107. MOVW.GT $8, R(LSHIFT)
  108. MOVW.GT $3, R(OFFSET)
  109. ADD $16, R(TS), R(TMP) /* do 16-byte chunks if possible */
  110. CMP R(TMP), R(TE)
  111. BLS _b1tail
  112. AND $~0x03, R(FROM) /* align source */
  113. MOVW (R(FROM)), R(BR0) /* prime first block register */
  114. _bu16loop:
  115. CMP R(TMP), R(TE)
  116. BLS _bu1tail
  117. MOVW R(BR0)<<R(LSHIFT), R(BW3)
  118. MOVM.DB.W (R(FROM)), [R(BR0)-R(BR3)]
  119. ORR R(BR3)>>R(RSHIFT), R(BW3)
  120. MOVW R(BR3)<<R(LSHIFT), R(BW2)
  121. ORR R(BR2)>>R(RSHIFT), R(BW2)
  122. MOVW R(BR2)<<R(LSHIFT), R(BW1)
  123. ORR R(BR1)>>R(RSHIFT), R(BW1)
  124. MOVW R(BR1)<<R(LSHIFT), R(BW0)
  125. ORR R(BR0)>>R(RSHIFT), R(BW0)
  126. MOVM.DB.W [R(BW0)-R(BW3)], (R(TE))
  127. B _bu16loop
  128. _bu1tail:
  129. ADD R(OFFSET), R(FROM)
  130. B _b1tail
  131. FW0 = 7
  132. FR0 = 8
  133. FW1 = 8
  134. FR1 = 9
  135. FW2 = 9
  136. FR2 = 10
  137. FW3 = 10
  138. FR3 = 11
  139. _funaligned:
  140. CMP $2, R(TMP)
  141. MOVW.LT $8, R(RSHIFT) /* (R(n+1)<<24)|(R(n)>>8) */
  142. MOVW.LT $24, R(LSHIFT)
  143. MOVW.LT $3, R(OFFSET)
  144. MOVW.EQ $16, R(RSHIFT) /* (R(n+1)<<16)|(R(n)>>16) */
  145. MOVW.EQ $16, R(LSHIFT)
  146. MOVW.EQ $2, R(OFFSET)
  147. MOVW.GT $24, R(RSHIFT) /* (R(n+1)<<8)|(R(n)>>24) */
  148. MOVW.GT $8, R(LSHIFT)
  149. MOVW.GT $1, R(OFFSET)
  150. SUB $16, R(TE), R(TMP) /* do 16-byte chunks if possible */
  151. CMP R(TMP), R(TS)
  152. BHS _f1tail
  153. AND $~0x03, R(FROM) /* align source */
  154. MOVW.P 4(R(FROM)), R(FR3) /* prime last block register, implicit write back */
  155. _fu16loop:
  156. CMP R(TMP), R(TS)
  157. BHS _fu1tail
  158. MOVW R(FR3)>>R(RSHIFT), R(FW0)
  159. MOVM.IA.W (R(FROM)), [R(FR0)-R(FR3)]
  160. ORR R(FR0)<<R(LSHIFT), R(FW0)
  161. MOVW R(FR0)>>R(RSHIFT), R(FW1)
  162. ORR R(FR1)<<R(LSHIFT), R(FW1)
  163. MOVW R(FR1)>>R(RSHIFT), R(FW2)
  164. ORR R(FR2)<<R(LSHIFT), R(FW2)
  165. MOVW R(FR2)>>R(RSHIFT), R(FW3)
  166. ORR R(FR3)<<R(LSHIFT), R(FW3)
  167. MOVM.IA.W [R(FW0)-R(FW3)], (R(TS))
  168. B _fu16loop
  169. _fu1tail:
  170. SUB R(OFFSET), R(FROM)
  171. B _f1tail