pbslba.s 8.0 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362
  1. /*
  2. * FAT Partition Boot Sector. Loaded at 0x7C00:
  3. * 8a pbslba.s; 8l -o pbslba -l -H3 -T0x7C00 pbslba.8
  4. * Will load the target at LOADSEG*16+LOADOFF, so the target
  5. * should be probably be loaded with LOADOFF added to the
  6. * -Taddress.
  7. * If LOADSEG is a multiple of 64KB and LOADOFF is 0 then
  8. * targets larger than 64KB can be loaded.
  9. *
  10. * This code is uses Enhanced BIOS Services for Disc Drives and
  11. * can be used with discs up to 137GB in capacity.
  12. *
  13. * It relies on the _volid field in the FAT header containing
  14. * the LBA of the root directory.
  15. */
  16. #include "x16.h"
  17. #include "mem.h"
  18. #define LOADSEG (0x10000/16) /* where to load code (64KB) */
  19. #define LOADOFF 0
  20. #define DIROFF 0x0200 /* where to read the root directory */
  21. /*
  22. * FAT directory entry.
  23. */
  24. #define Dname 0x00
  25. #define Dext 0x08
  26. #define Dattr 0x0B
  27. #define Dtime 0x16
  28. #define Ddate 0x18
  29. #define Dstart 0x1A
  30. #define Dlengthlo 0x1C
  31. #define Dlengthhi 0x1E
  32. #define Dirsz 0x20
  33. /*
  34. * Data is kept on the stack, indexed by rBP.
  35. */
  36. #define Xdap 0x00 /* disc address packet */
  37. #define Xrootsz 0x10 /* file data area */
  38. #define Xdrive 0x12 /* boot drive, passed by BIOS or MBR */
  39. #define Xtotal 0x14 /* sum of allocated data above */
  40. TEXT _magic(SB), $0
  41. BYTE $0xEB; BYTE $0x3C; /* jmp .+ 0x3C (_start0x3E) */
  42. BYTE $0x90 /* nop */
  43. TEXT _version(SB), $0
  44. BYTE $0x00; BYTE $0x00; BYTE $0x00; BYTE $0x00;
  45. BYTE $0x00; BYTE $0x00; BYTE $0x00; BYTE $0x00
  46. TEXT _sectsize(SB), $0
  47. BYTE $0x00; BYTE $0x00
  48. TEXT _clustsize(SB), $0
  49. BYTE $0x00
  50. TEXT _nresrv(SB), $0
  51. BYTE $0x00; BYTE $0x00
  52. TEXT _nfats(SB), $0
  53. BYTE $0x00
  54. TEXT _rootsize(SB), $0
  55. BYTE $0x00; BYTE $0x00
  56. TEXT _volsize(SB), $0
  57. BYTE $0x00; BYTE $0x00
  58. TEXT _mediadesc(SB), $0
  59. BYTE $0x00
  60. TEXT _fatsize(SB), $0
  61. BYTE $0x00; BYTE $0x00
  62. TEXT _trksize(SB), $0
  63. BYTE $0x00; BYTE $0x00
  64. TEXT _nheads(SB), $0
  65. BYTE $0x00; BYTE $0x00
  66. TEXT _nhiddenlo(SB), $0
  67. BYTE $0x00; BYTE $0x00
  68. TEXT _nhiddenhi(SB), $0
  69. BYTE $0x00; BYTE $0x00;
  70. TEXT _bigvolsize(SB), $0
  71. BYTE $0x00; BYTE $0x00; BYTE $0x00; BYTE $0x00;
  72. TEXT _driveno(SB), $0
  73. BYTE $0x00
  74. TEXT _reserved0(SB), $0
  75. BYTE $0x00
  76. TEXT _bootsig(SB), $0
  77. BYTE $0x00
  78. TEXT _volid(SB), $0
  79. BYTE $0x00; BYTE $0x00; BYTE $0x00; BYTE $0x00;
  80. TEXT _label(SB), $0
  81. BYTE $0x00; BYTE $0x00; BYTE $0x00; BYTE $0x00;
  82. BYTE $0x00; BYTE $0x00; BYTE $0x00; BYTE $0x00
  83. BYTE $0x00; BYTE $0x00; BYTE $0x00
  84. TEXT _type(SB), $0
  85. BYTE $0x00; BYTE $0x00; BYTE $0x00; BYTE $0x00;
  86. BYTE $0x00; BYTE $0x00; BYTE $0x00; BYTE $0x00;
  87. _start0x3E:
  88. CLI
  89. CLR(rAX)
  90. MTSR(rAX, rSS) /* 0000 -> rSS */
  91. MTSR(rAX, rDS) /* 0000 -> rDS, source segment */
  92. MTSR(rAX, rES)
  93. LWI(_magic-Xtotal(SB), rSP)
  94. MW(rSP, rBP) /* set the indexed-data pointer */
  95. SBPB(rDL, Xdrive) /* save the boot drive */
  96. /* booting from a CD starts us at 7C0:0. Move to 0:7C00 */
  97. PUSHR(rAX)
  98. LWI(_nxt(SB), rAX)
  99. PUSHR(rAX)
  100. BYTE $0xCB /* FAR RET */
  101. TEXT _nxt(SB), $0
  102. STI
  103. LWI(confidence(SB), rSI) /* for that warm, fuzzy feeling */
  104. CALL16(BIOSputs(SB))
  105. LBI(0x41, rAH) /* check extensions present */
  106. LWI(0x55AA, rBX)
  107. LXB(Xdrive, xBP, rDL) /* drive */
  108. BIOSCALL(0x13) /* CF set on failure */
  109. JCS _jmp01
  110. CMPI(0xAA55, rBX)
  111. JNE _jmp01
  112. ANDI(0x0001, rCX)
  113. JEQ _jmp01
  114. /* rCX contains 0x0001 */
  115. SBPWI(0x0010, Xdap+0) /* reserved + packet size */
  116. SBPWI(rCX, Xdap+2) /* reserved + # of blocks to transfer */
  117. DEC(rCX)
  118. SBPW(rCX, Xdap+12)
  119. SBPW(rCX, Xdap+14)
  120. CALL16(dreset(SB))
  121. _jmp00:
  122. LW(_volid(SB), rAX) /* Xrootlo */
  123. LW(_volid+2(SB), rDX) /* Xroothi */
  124. LWI(_magic+DIROFF(SB), rBX)
  125. CALL16(BIOSread(SB)) /* read the root directory */
  126. LWI((512/Dirsz), rBX)
  127. LWI(_magic+DIROFF(SB), rDI) /* compare first directory entry */
  128. _cmp00:
  129. PUSHR(rDI) /* save for later if it matches */
  130. LWI(bootfile(SB), rSI)
  131. LWI(Dattr, rCX)
  132. REP
  133. CMPSB
  134. POPR(rDI)
  135. JEQ _jmp02
  136. DEC(rBX)
  137. JEQ _jmp01
  138. ADDI(Dirsz, rDI)
  139. JMP _cmp00
  140. _jmp01:
  141. CALL16(buggery(SB))
  142. _jmp02:
  143. CLR(rBX) /* a handy value */
  144. LW(_rootsize(SB), rAX) /* calculate and save Xrootsz */
  145. LWI(Dirsz, rCX)
  146. MUL(rCX)
  147. LW(_sectsize(SB), rCX)
  148. PUSHR(rCX)
  149. DEC(rCX)
  150. ADD(rCX, rAX)
  151. ADC(rBX, rDX)
  152. POPR(rCX) /* _sectsize(SB) */
  153. DIV(rCX)
  154. PUSHR(rAX) /* Xrootsz */
  155. /*
  156. * rDI points to the matching directory entry.
  157. */
  158. LXW(Dstart, xDI, rAX) /* starting sector address */
  159. DEC(rAX) /* that's just the way it is */
  160. DEC(rAX)
  161. LB(_clustsize(SB), rCL)
  162. CLRB(rCH)
  163. MUL(rCX)
  164. LW(_volid(SB), rCX) /* Xrootlo */
  165. ADD(rCX, rAX)
  166. LW(_volid+2(SB), rCX) /* Xroothi */
  167. ADC(rCX, rDX)
  168. POPR(rCX) /* Xrootsz */
  169. ADD(rCX, rAX)
  170. ADC(rBX, rDX)
  171. PUSHR(rAX) /* calculate how many sectors to read */
  172. PUSHR(rDX)
  173. LXW(Dlengthlo, xDI, rAX)
  174. LXW(Dlengthhi, xDI, rDX)
  175. LW(_sectsize(SB), rCX)
  176. PUSHR(rCX)
  177. DEC(rCX)
  178. ADD(rCX, rAX)
  179. ADC(rBX, rDX)
  180. POPR(rCX) /* _sectsize(SB) */
  181. DIV(rCX)
  182. MW(rAX, rCX)
  183. POPR(rDX)
  184. POPR(rAX)
  185. LWI(LOADSEG, rBX) /* address to load into (seg+offset) */
  186. MTSR(rBX, rES) /* seg */
  187. LWI(LOADOFF, rBX) /* offset */
  188. _readboot:
  189. CALL16(BIOSread(SB)) /* read the sector */
  190. LW(_sectsize(SB), rDI) /* bump addresses/counts */
  191. ADD(rDI, rBX)
  192. JCC _incsecno
  193. MFSR(rES, rDI) /* next 64KB segment */
  194. ADDI(0x1000, rDI)
  195. MTSR(rDI, rES)
  196. _incsecno:
  197. CLR(rDI)
  198. INC(rAX)
  199. ADC(rDI, rDX)
  200. LOOP _readboot
  201. LWI(LOADSEG, rDI) /* set rDS for loaded code */
  202. MTSR(rDI, rDS)
  203. FARJUMP16(LOADSEG, LOADOFF) /* no deposit, no return */
  204. TEXT buggery(SB), $0
  205. LWI(error(SB), rSI)
  206. CALL16(BIOSputs(SB))
  207. _wait:
  208. CLR(rAX) /* wait for almost any key */
  209. BIOSCALL(0x16)
  210. _reset:
  211. CLR(rBX) /* set ES segment for BIOS area */
  212. MTSR(rBX, rES)
  213. LWI(0x0472, rBX) /* warm-start code address */
  214. LWI(0x1234, rAX) /* warm-start code */
  215. POKEW /* MOVW AX, ES:[BX] */
  216. FARJUMP16(0xFFFF, 0x0000) /* reset */
  217. /*
  218. * Read a sector from a disc. On entry:
  219. * rDX:rAX sector number
  220. * rES:rBX buffer address
  221. */
  222. TEXT BIOSread(SB), $0
  223. LWI(5, rDI) /* retry count (ATAPI ZIPs suck) */
  224. _retry:
  225. PUSHA /* may be trashed by BIOSCALL */
  226. SBPW(rBX, Xdap+4) /* transfer buffer :offset */
  227. MFSR(rES, rDI) /* transfer buffer seg: */
  228. SBPW(rDI, Xdap+6)
  229. SBPW(rAX, Xdap+8) /* LBA (64-bits) */
  230. SBPW(rDX, Xdap+10)
  231. MW(rBP, rSI) /* disk address packet */
  232. LBI(0x42, rAH) /* extended read */
  233. LBPB(Xdrive, rDL) /* form drive */
  234. BIOSCALL(0x13) /* CF set on failure */
  235. JCC _BIOSreadret
  236. POPA
  237. DEC(rDI) /* too many retries? */
  238. JEQ _ioerror
  239. CALL16(dreset(SB))
  240. JMP _retry
  241. _ioerror:
  242. LWI(ioerror(SB), rSI)
  243. CALL16(BIOSputs(SB))
  244. JMP _wait
  245. _BIOSreadret:
  246. POPA
  247. RET
  248. TEXT dreset(SB), $0
  249. PUSHA
  250. CLR(rAX) /* rAH == 0 == reset disc system */
  251. LBPB(Xdrive, rDL)
  252. BIOSCALL(0x13)
  253. ORB(rAH, rAH) /* status (0 == success) */
  254. POPA
  255. JNE _ioerror
  256. RET
  257. /*
  258. * Output a string to the display.
  259. * String argument is in rSI.
  260. */
  261. TEXT BIOSputs(SB), $0
  262. PUSHA
  263. CLR(rBX)
  264. _BIOSputs:
  265. LODSB
  266. ORB(rAL, rAL)
  267. JEQ _BIOSputsret
  268. LBI(0x0E, rAH)
  269. BIOSCALL(0x10)
  270. JMP _BIOSputs
  271. _BIOSputsret:
  272. POPA
  273. RET
  274. /* "Bad format or I/O error\r\nPress almost any key to reboot..." */
  275. TEXT error(SB), $0
  276. BYTE $'B'; BYTE $'a'; BYTE $'d'; BYTE $' ';
  277. BYTE $'f'; BYTE $'o'; BYTE $'r'; BYTE $'m';
  278. BYTE $'a'; BYTE $'t'; BYTE $' '; BYTE $'o';
  279. BYTE $'r'; BYTE $' ';
  280. /* "I/O error\r\nPress almost any key to reboot..." */
  281. TEXT ioerror(SB), $0
  282. BYTE $'I'; BYTE $'/'; BYTE $'O'; BYTE $' ';
  283. BYTE $'e'; BYTE $'r'; BYTE $'r'; BYTE $'o';
  284. BYTE $'r'; BYTE $'\r';BYTE $'\n';
  285. BYTE $'P'; BYTE $'r'; BYTE $'e'; BYTE $'s';
  286. BYTE $'s'; BYTE $' '; BYTE $'a'; BYTE $' ';
  287. BYTE $'k'; BYTE $'e'; BYTE $'y';
  288. BYTE $' '; BYTE $'t'; BYTE $'o'; BYTE $' ';
  289. BYTE $'r'; BYTE $'e'; BYTE $'b'; BYTE $'o';
  290. BYTE $'o'; BYTE $'t';
  291. BYTE $'.'; BYTE $'.'; BYTE $'.';
  292. BYTE $'\z';
  293. #ifdef USEBCOM
  294. /* "B COM" */
  295. TEXT bootfile(SB), $0
  296. BYTE $'B'; BYTE $' '; BYTE $' '; BYTE $' ';
  297. BYTE $' '; BYTE $' '; BYTE $' '; BYTE $' ';
  298. BYTE $'C'; BYTE $'O'; BYTE $'M';
  299. BYTE $'\z';
  300. #else
  301. /* "9LOAD " */
  302. TEXT bootfile(SB), $0
  303. BYTE $'9'; BYTE $'L'; BYTE $'O'; BYTE $'A';
  304. BYTE $'D'; BYTE $' '; BYTE $' '; BYTE $' ';
  305. BYTE $' '; BYTE $' '; BYTE $' ';
  306. BYTE $'\z';
  307. #endif /* USEBCOM */
  308. /* "PBS..." */
  309. TEXT confidence(SB), $0
  310. BYTE $'P'; BYTE $'B'; BYTE $'S'; BYTE $'2';
  311. BYTE $'.'; BYTE $'.'; BYTE $'.';
  312. BYTE $'\z';