mkdevc 4.1 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191
  1. #!/bin/rc
  2. awk -v 'objtype='$objtype -v 'pwd='`{pwd} '
  3. BEGIN{
  4. if(ARGC < 2)
  5. exit
  6. }
  7. /^[ \t]*$/{
  8. next;
  9. }
  10. /^#/{
  11. next;
  12. }
  13. collect && /^[^ \t]/{
  14. collect = 0;
  15. }
  16. collect && section ~ "dev"{
  17. dev[ndev++] = $1;
  18. if($1 ~ "ad")
  19. devad = 1;
  20. else if($1 ~ "sd")
  21. devsd = 1;
  22. else if($1 ~ "uart")
  23. devuart = 1;
  24. else if($1 ~ "vga")
  25. devvga = 1;
  26. for(i = 2; i <= NF; i++){
  27. if($i ~ "dma" && objtype ~ "(386|alpha|amd64)")
  28. i8237dma++;
  29. }
  30. }
  31. collect && section ~ "ip"{
  32. ip[nip++] = $1;
  33. }
  34. collect && section ~ "link"{
  35. link[nlink++] = $1;
  36. }
  37. collect && section ~ "misc"{
  38. sub(/^[ \t]*/, "");
  39. misc[nmisc++] = $1;
  40. if($1 ~ "^arch.*")
  41. arch[narch++] = $1;
  42. else if($1 ~ "^ad.*")
  43. adifc[nadifc++] = $1;
  44. else if($1 ~ "^sd.*")
  45. sdifc[nsdifc++] = $1;
  46. else if($1 ~ "^uart.*")
  47. physuart[nphysuart++] = substr($1, 5, length($1)-4) "physuart";
  48. else if($1 ~ "^vga.*"){
  49. if(NF == 1)
  50. vgadev[nvgadev++] = $1;
  51. else for(i = 2; i <= NF; i++){
  52. if($i ~ "[+]cur")
  53. vgadev[nvgadev++] = $1;
  54. if($i ~ "[+=]cur")
  55. vgacur[nvgacur++] = $1;
  56. }
  57. }
  58. }
  59. collect && section ~ "port"{
  60. sub(/^[ \t]*/, "");
  61. port[nport++] = $0;
  62. }
  63. $0 ~ /^[^ \t]/{
  64. if($0 ~ "(bootdir|dev|ip|link|misc|port)"){
  65. section = $0;
  66. collect = 1;
  67. }
  68. next;
  69. }
  70. END{
  71. if(ARGC < 2)
  72. exit "usage"
  73. printf "#include \"u.h\"\n";
  74. printf "#include \"../port/lib.h\"\n";
  75. printf "#include \"mem.h\"\n";
  76. printf "#include \"dat.h\"\n";
  77. printf "#include \"fns.h\"\n";
  78. printf "#include \"io.h\"\n";
  79. printf "#include \"../port/error.h\"\n\n";
  80. for(i = 0; i < ndev; i++)
  81. printf "extern Dev %sdevtab;\n", dev[i];
  82. printf "Dev* devtab[]={\n";
  83. for(i = 0; i < ndev; i++)
  84. printf "\t&%sdevtab,\n", dev[i];
  85. printf "\tnil,\n};\n\n";
  86. if(objtype ~ "(386|alpha|amd64)"){
  87. alloc = "nil";
  88. if(i8237dma){
  89. printf "extern void _i8237alloc(void);\n";
  90. alloc = "_i8237alloc";
  91. }
  92. printf "void (*i8237alloc)(void) = %s;\n", alloc;
  93. printf "int i8237dma = %d;\n\n", i8237dma;
  94. }
  95. for(i = 0; i < nlink; i++)
  96. printf "extern void %slink(void);\n", link[i];
  97. printf "void links(void){\n";
  98. print "\tbootlinks();\n";
  99. for(i = 0; i < nlink; i++)
  100. printf "\t%slink();\n", link[i];
  101. printf "}\n\n";
  102. if(narch || objtype ~ "386"){
  103. for(i = 0; i < narch; i++)
  104. printf "extern PCArch %s;\n", arch[i];
  105. printf "PCArch* knownarch[] = {\n";
  106. for(i = 0; i < narch; i++)
  107. printf "\t&%s,\n", arch[i];
  108. printf "\tnil,\n};\n\n";
  109. }
  110. if(devad){
  111. printf "#include \"../port/ad.h\"\n";
  112. for(i = 0; i < nadifc; i++)
  113. printf "extern ADifc %sifc;\n", adifc[i];
  114. printf "ADifc* adifc[] = {\n";
  115. for(i = 0; i < nadifc; i++)
  116. printf "\t&%sifc,\n", adifc[i];
  117. printf "\tnil,\n};\n\n";
  118. }
  119. if(devsd){
  120. printf "#include \"../port/sd.h\"\n";
  121. for(i = 0; i < nsdifc; i++)
  122. printf "extern SDifc %sifc;\n", sdifc[i];
  123. printf "SDifc* sdifc[] = {\n";
  124. for(i = 0; i < nsdifc; i++)
  125. printf "\t&%sifc,\n", sdifc[i];
  126. printf "\tnil,\n};\n\n";
  127. }
  128. if(devuart){
  129. for(i = 0; i < nphysuart; i++)
  130. printf "extern PhysUart %s;\n", physuart[i];
  131. printf "PhysUart* physuart[] = {\n";
  132. for(i = 0; i < nphysuart; i++)
  133. printf "\t&%s,\n", physuart[i];
  134. printf "\tnil,\n};\n\n";
  135. }
  136. if(devvga){
  137. printf "#define Image IMAGE\n";
  138. printf "#include <draw.h>\n";
  139. printf "#include <memdraw.h>\n";
  140. printf "#include <cursor.h>\n";
  141. printf "#include \"screen.h\"\n";
  142. for(i = 0; i < nvgadev; i++)
  143. printf "extern VGAdev %sdev;\n", vgadev[i];
  144. printf "VGAdev* vgadev[] = {\n";
  145. for(i = 0; i < nvgadev; i++)
  146. printf "\t&%sdev,\n", vgadev[i];
  147. printf "\tnil,\n};\n\n";
  148. for(i = 0; i < nvgacur; i++)
  149. printf "extern VGAcur %scur;\n", vgacur[i];
  150. printf "VGAcur* vgacur[] = {\n";
  151. for(i = 0; i < nvgacur; i++)
  152. printf "\t&%scur,\n", vgacur[i];
  153. printf "\tnil,\n};\n\n";
  154. }
  155. if(nip){
  156. printf "#include \"../ip/ip.h\"\n";
  157. for(i = 0; i < nip; i++)
  158. printf "extern void %sinit(Fs*);\n", ip[i];
  159. printf "void (*ipprotoinit[])(Fs*) = {\n";
  160. for(i = 0; i < nip; i++)
  161. printf "\t%sinit,\n", ip[i];
  162. printf "\tnil,\n};\n\n";
  163. }
  164. if(nport){
  165. for(i = 0; i < nport; i++)
  166. printf "%s\n", port[i];
  167. printf "\n";
  168. }
  169. printf "char* conffile = \"%s/%s\";\n", pwd, ARGV[1];
  170. printf "ulong kerndate = KERNDATE;\n";
  171. exit
  172. }' $*