mkdevc 4.1 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186
  1. #!/bin/rc
  2. awk -v 'objtype='$objtype '
  3. BEGIN{
  4. if(ARGC < 2)
  5. exit
  6. }
  7. /^[ \t]*$/{
  8. next;
  9. }
  10. /^#/{
  11. next;
  12. }
  13. collect && /^[^ \t]/{
  14. collect = 0;
  15. }
  16. collect && section ~ "dev"{
  17. dev[ndev++] = $1;
  18. if($1 ~ "ad")
  19. devad = 1;
  20. else if($1 ~ "sd")
  21. devsd = 1;
  22. else if($1 ~ "uart")
  23. devuart = 1;
  24. else if($1 ~ "vga")
  25. devvga = 1;
  26. for(i = 2; i <= NF; i++){
  27. if($i ~ "dma" && objtype ~ "(386|alpha|amd64)")
  28. i8237dma++;
  29. }
  30. }
  31. collect && section ~ "ip"{
  32. ip[nip++] = $1;
  33. }
  34. collect && section ~ "link"{
  35. link[nlink++] = $1;
  36. }
  37. collect && section ~ "misc"{
  38. misc[nmisc++] = $1;
  39. if($1 ~ "^arch.*")
  40. arch[narch++] = $1;
  41. else if($1 ~ "^ad.*")
  42. adifc[nadifc++] = $1;
  43. else if($1 ~ "^sd.*")
  44. sdifc[nsdifc++] = $1;
  45. else if($1 ~ "^uart.*")
  46. physuart[nphysuart++] = substr($1, 5, length($1)-4) "physuart";
  47. else if($1 ~ "^vga.*"){
  48. if(NF == 1)
  49. vgadev[nvgadev++] = $1;
  50. else for(i = 2; i <= NF; i++){
  51. if($i ~ "[+]cur")
  52. vgadev[nvgadev++] = $1;
  53. if($i ~ "[+=]cur")
  54. vgacur[nvgacur++] = $1;
  55. }
  56. }
  57. }
  58. collect && section ~ "port"{
  59. port[nport++] = $0;
  60. }
  61. $0 ~ /^[^ \t]/{
  62. if($0 ~ "(bootdir|dev|ip|link|misc|port)"){
  63. section = $0;
  64. collect = 1;
  65. }
  66. next;
  67. }
  68. END{
  69. if(ARGC < 2)
  70. exit "usage"
  71. printf "#include \"u.h\"\n";
  72. printf "#include \"../port/lib.h\"\n";
  73. printf "#include \"mem.h\"\n";
  74. printf "#include \"dat.h\"\n";
  75. printf "#include \"fns.h\"\n";
  76. printf "#include \"io.h\"\n";
  77. printf "#include \"../port/error.h\"\n\n";
  78. for(i = 0; i < ndev; i++)
  79. printf "extern Dev %sdevtab;\n", dev[i];
  80. printf "Dev* devtab[]={\n";
  81. for(i = 0; i < ndev; i++)
  82. printf "\t&%sdevtab,\n", dev[i];
  83. printf "\tnil,\n};\n\n";
  84. if(objtype ~ "(386|alpha|amd64)"){
  85. alloc = "nil";
  86. if(i8237dma){
  87. printf "extern void _i8237alloc(void);\n";
  88. alloc = "_i8237alloc";
  89. }
  90. printf "void (*i8237alloc)(void) = %s;\n", alloc;
  91. printf "int i8237dma = %d;\n\n", i8237dma;
  92. }
  93. for(i = 0; i < nlink; i++)
  94. printf "extern void %slink(void);\n", link[i];
  95. printf "void links(void){\n";
  96. print "\tbootlinks();\n";
  97. for(i = 0; i < nlink; i++)
  98. printf "\t%slink();\n", link[i];
  99. printf "}\n\n";
  100. if(narch || objtype ~ "386"){
  101. for(i = 0; i < narch; i++)
  102. printf "extern PCArch %s;\n", arch[i];
  103. printf "PCArch* knownarch[] = {\n";
  104. for(i = 0; i < narch; i++)
  105. printf "\t&%s,\n", arch[i];
  106. printf "\tnil,\n};\n\n";
  107. }
  108. if(devad){
  109. printf "#include \"../port/ad.h\"\n";
  110. for(i = 0; i < nadifc; i++)
  111. printf "extern ADifc %sifc;\n", adifc[i];
  112. printf "ADifc* adifc[] = {\n";
  113. for(i = 0; i < nadifc; i++)
  114. printf "\t&%sifc,\n", adifc[i];
  115. printf "\tnil,\n};\n\n";
  116. }
  117. if(devsd){
  118. printf "#include \"../port/sd.h\"\n";
  119. for(i = 0; i < nsdifc; i++)
  120. printf "extern SDifc %sifc;\n", sdifc[i];
  121. printf "SDifc* sdifc[] = {\n";
  122. for(i = 0; i < nsdifc; i++)
  123. printf "\t&%sifc,\n", sdifc[i];
  124. printf "\tnil,\n};\n\n";
  125. }
  126. if(devuart){
  127. for(i = 0; i < nphysuart; i++)
  128. printf "extern PhysUart %s;\n", physuart[i];
  129. printf "PhysUart* physuart[] = {\n";
  130. for(i = 0; i < nphysuart; i++)
  131. printf "\t&%s,\n", physuart[i];
  132. printf "\tnil,\n};\n\n";
  133. }
  134. if(devvga){
  135. printf "#define Image IMAGE\n";
  136. printf "#include <draw.h>\n";
  137. printf "#include <memdraw.h>\n";
  138. printf "#include <cursor.h>\n";
  139. printf "#include \"screen.h\"\n";
  140. for(i = 0; i < nvgadev; i++)
  141. printf "extern VGAdev %sdev;\n", vgadev[i];
  142. printf "VGAdev* vgadev[] = {\n";
  143. for(i = 0; i < nvgadev; i++)
  144. printf "\t&%sdev,\n", vgadev[i];
  145. printf "\tnil,\n};\n\n";
  146. for(i = 0; i < nvgacur; i++)
  147. printf "extern VGAcur %scur;\n", vgacur[i];
  148. printf "VGAcur* vgacur[] = {\n";
  149. for(i = 0; i < nvgacur; i++)
  150. printf "\t&%scur,\n", vgacur[i];
  151. printf "\tnil,\n};\n\n";
  152. }
  153. if(nip){
  154. printf "#include \"../ip/ip.h\"\n";
  155. for(i = 0; i < nip; i++)
  156. printf "extern void %sinit(Fs*);\n", ip[i];
  157. printf "void (*ipprotoinit[])(Fs*) = {\n";
  158. for(i = 0; i < nip; i++)
  159. printf "\t%sinit,\n", ip[i];
  160. printf "\tnil,\n};\n\n";
  161. }
  162. for(i = 0; i < nport; i++)
  163. printf "%s\n", port[i];
  164. printf "char* conffile = \"%s\";\n", ARGV[1];
  165. printf "ulong kerndate = KERNDATE;\n";
  166. exit
  167. }' $*